home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 04 (1982-12)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 04 (1982-12)(Softdisk)(Side B).do / CRAZY STORIES.bas < prev    next >
BASIC Source File  |  1996-12-24  |  10KB  |  113 lines
  1. 10  REM =========================
  2. 20  REM =     CRAZY STORIES     =
  3. 30  REM =    BY SANDY SMITH     =
  4. 40  REM =      INSPIRED BY      =
  5. 50  REM = 3.8 THRILLION STORIES =
  6. 60  REM =  WRITTEN IN INTEGER   =
  7. 70  REM = BY DANIEL A. LAMBERT  =
  8. 80  REM =========================
  9. 100  REM *** TITLE PAGE
  10. 110  HOME : INVERSE : FOR I = 1 TO 24: PRINT  SPC( 40): NEXT : REM   EASY WAY TO CREATE INVERSE SCREEN
  11. 120  VTAB 3:A$ = "C R A Z Y  S T O R I E S": GOSUB 1030:A$ = "- - - - -  - - - - - - -": GOSUB 1030
  12. 130  VTAB 6:A$ = "A BUNCH OF TALL TALES": GOSUB 1030:A$ = "FOR YOUR READING PLEASURE": GOSUB 1030
  13. 140  VTAB 10:A$ = "BY SANDY SMITH": GOSUB 1030
  14. 150  VTAB 13:A$ = "INSPIRED BY": GOSUB 1030:A$ = "'3.8 THRILLION STORIES'": GOSUB 1030:A$ = "AN INTEGER PROGRAM WRITTEN": GOSUB 1030:A$ = "BY DANIEL A. LAMBERT": GOSUB 1030
  15. 160  PRINT : PRINT :A$ = "WITH THANKS TO": GOSUB 1030:A$ = "SOFTDISK SUBSCRIBERS": GOSUB 1030:A$ = "FOR PROVIDING": GOSUB 1030:A$ = "SOME OF THE SUBROUTINES": GOSUB 1030: NORMAL 
  16. 170  VTAB 23: HTAB 14: PRINT "<<PRESS A KEY>>": WAIT  -16384,128: POKE  -16368,0: GOSUB 1210
  17. 180  VTAB 12: HTAB 2: PRINT "THE STORYTELLER WILL BE HERE SOON....": FOR D = 1 TO 3000: NEXT 
  18. 200  REM *** INITIALIZE
  19. 210  DIM N1$(24),N2$(24),V1$(24),V2$(24),P1$(24),P2$(24),P3$(24),H$(24),WN$(24),WH$(24):SN = 1
  20. 220 A =  PEEK(78):A = A +1: FOR X = 1 TO A: POKE 202,A:N =  RND(1): NEXT : REM RANDOM NUMBER SEED
  21. 230  FOR I = 1 TO 24: READ N1$(I): NEXT : FOR I = 1 TO 24: READ N2$(I): NEXT 
  22. 240  FOR I = 1 TO 24: READ V1$(I): NEXT : FOR I = 1 TO 24: READ V2$(I): NEXT 
  23. 250  FOR I = 1 TO 24: READ P1$(I): NEXT : FOR I = 1 TO 24: READ P2$(I): NEXT : FOR I = 1 TO 24: READ P3$(I): NEXT 
  24. 260  FOR I = 1 TO 24: READ H$(I): NEXT : FOR I = 1 TO 24: READ WN$(I): NEXT : FOR I = 1 TO 24: READ WH$(I): NEXT 
  25. 300  REM *** CREATE THE STORY
  26. 310  HOME : VTAB 2: HTAB 12: INVERSE : PRINT " CRAZY STORY #";SN;" ": NORMAL 
  27. 320  VTAB 6: HTAB 3:A$ = "ONCE UPON A TIME...": GOSUB 1070
  28. 330  GOSUB 1010:A$ = N1$(R) +" AND": VTAB 8: GOSUB 1070
  29. 340  GOSUB 1010:A$ = N2$(R): GOSUB 1070
  30. 350  GOSUB 1010:A$ = "WERE " +V1$(R) +"ING ": GOSUB 1010:A$ = A$ +P1$(R): GOSUB 1070
  31. 360  GOSUB 1010:A$ = "WHEN THEY " +WN$(R): GOSUB 1070
  32. 370  GOSUB 1010:A$ = P2$(R): GOSUB 1070
  33. 380  GOSUB 1010:A$ = "WHO " +H$(R): GOSUB 1070
  34. 390  GOSUB 1010:A$ = "WHERE " +WH$(R): GOSUB 1070
  35. 400  GOSUB 1010:A$ = V2$(R) +"ING ": GOSUB 1010:A$ = A$ +P3$(R) +".": GOSUB 1070
  36. 410  PRINT : HTAB 3:A$ = "AND THEY LIVED HAPPILY EVER AFTER!": GOSUB 1070
  37. 420  VTAB 23: CALL  -868: INPUT "DO YOU WANT ANOTHER STORY? (Y/N) ";Q$: IF Q$ = "N"  THEN  GOSUB 1210: VTAB 12: HTAB 18: PRINT "BYE!!": END 
  38. 430  IF Q$ < >"Y"  THEN 420
  39. 440 F =  FRE(0): GOSUB 1210:SN = SN +1: GOTO 310
  40. 1000  REM *** SUBROUTINES
  41. 1010 R =  INT( RND(1) *24) +1: RETURN : REM RANDOM NUMBER GENERATOR
  42. 1020  REM ** STRING PULL
  43. 1030 CV =  PEEK(37):A1$ = "": FOR X = 1 TO 20 - LEN(A$)/2:A1$ = A1$ +" ": NEXT :A$ = A1$ +A$ +A1$: IF  LEN(A$)/2 < > INT( LEN(A$)/2)  THEN A$ = A$ +" "
  44. 1040  FOR X = 1 TO 20:PR$ =  LEFT$(A$,X) + RIGHT$(A$,X): VTAB CV: HTAB 21 -X: PRINT PR$: NEXT : FOR D = 1 TO 800: NEXT : RETURN 
  45. 1050  REM ** PRETTY PRINT ROUTINE ADAPTED FROM BEAGLE BROS    TIP BOOK #4
  46. 1060  REM PUT DESIRED OUTPUT IN   A$, POSITION CURSOR USING  VTAB & HTAB AND GOSUB 1070
  47. 1070 CURSR$ = "->": SPEED= 200
  48. 1080  FOR X = 1 TO  LEN(CURSR$):CURSR$ = CURSR$ + CHR$(8): NEXT 
  49. 1090  FOR X = 1 TO  LEN(A$): INVERSE : PRINT CURSR$;: NORMAL :M$ =  MID$ (A$,X,1): PRINT M$;: IF M$ = " "  OR M$ = "."  THEN  FOR Y = 1 TO 25 +150 *(M$ = "."): NEXT 
  50. 1100  IF M$ < >" "  THEN  FOR Y = 1 TO 2:S =  PEEK( -16336): NEXT 
  51. 1110  NEXT : CALL  -868: PRINT : SPEED= 255: RETURN 
  52. 1200  REM *** PAGE WIPES
  53. 1210  VTAB 1: HTAB 1: GOSUB 1220: VTAB 1: HTAB 1: RETURN 
  54. 1220 R =  INT( RND(1) *8) +1: ON R GOSUB 1230,1240,1250,1260,1270,1280,1290,1300
  55. 1230  FOR X = 1 TO 12: VTAB X: CALL  -868: VTAB 25 -X: CALL  -868: FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM  FROM TOP & BOTTOM TO MIDDLE
  56. 1240  FOR X = 13 TO 24: HTAB 1: VTAB X: CALL  -868: VTAB 25 -X: CALL  -868: FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM FROM CENTER TO TOP & BOTTOM
  57. 1250  FOR X = 1 TO 24: VTAB X: CALL  -868: FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM  FROM TOP TO BOTTOM
  58. 1260  FOR X = 1 TO 24: CALL  -912: FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM   SCROLL OFF TOP
  59. 1270  FOR X = 38 TO 0  STEP  -1: POKE 32,X: POKE 33,40 -X: HOME : FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM     RIGHT TO LEFT
  60. 1280  FOR X = 1 TO 12: POKE 34,12 -X: POKE 35,12 +X: POKE 33,4 +3 *X: POKE 32,24 -2 *X: HOME : FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM       EXPANDING BOX
  61. 1290 X1 = 1:Y1 = 1: GOSUB 1295:X1 = 12:Y1 = 21: GOSUB 1295:X1 = 1: GOSUB 1295:X1 = 12:Y1 = 1: GOSUB 1295: RETURN 
  62. 1295  FOR X = X1 TO X1 +11: VTAB X: FOR Y = Y1 TO Y1 +19: HTAB Y: PRINT " ";: NEXT : NEXT : RETURN : REM     QUARTER WIPE
  63. 1300  FOR X = 2 TO 40: POKE 33,X: HOME : FOR D = 1 TO 100: NEXT : NEXT : RETURN : REM   FROM LEFT TO RIGHT
  64. 2000  REM ** DATA FOR FIRST NAMES APPEARING - N1$( )
  65. 2010  DATA ARCHIE BUNKER,BILLY THE KID,JIMINY CRICKET,THE EASTER BUNNY,PETER PAN,SUPERMAN,LOIS LANE,CHRISTOPHER ROBIN,JACK AND JILL,THREE BLIND MICE
  66. 2020  DATA LASSIE,PETER RABBIT,ALI BABA,ROBIN HOOD,TOM THUMB,PAUL BUNYAN,MARY POPPINS,BILBO BAGGINS,LITTLE BO PEEP,HANSEL AND GRETEL
  67. 2030  DATA RAPUNZUL,HENNY-PENNY,ALADDIN,OLD MOTHER HUBBARD
  68. 2050  REM  ** DATA FOR 2ND NAMES APPEARING - N2$( )
  69. 2060  DATA TINKERBELL,WONDER WOMAN,SANTA CLAUS,FROSTY THE SNOWMAN,BUGS BUNNY,THE PINK PANTHER,THE JOLLY GREEN GIANT,FLASH GORDON,PORKY PIG,THE FONZ
  70. 2070  DATA WOODSTOCK AND SNOOPY,KERMIT THE FROG,CHARLIE BROWN,THE COOKIE MONSTER,MR. ROGERS,CAPTAIN KANGAROO,MISS PIGGY,THE INCREDIBLE HULK,ZORRO,RONALD MCDONALD
  71. 2080  DATA THE GREEN ARROW,MR. GREEN JEANS,SNOW WHITE,CINDERELLA
  72. 2100  REM ** DATA FOR FIRST VERB PHRASES - V1$( )
  73. 2110  DATA KICK,SING,PLAY,SHOUT,RUNN,FIGHT,CRY,READ,CLIMB,SWING
  74. 2120  DATA DAY DREAM,LAUGH,FREEZ,GROAN,SWEAT,SAIL,CRAWL,CLEAN,SNOOP,JOGG
  75. 2130  DATA YODEL,STREAK,SLEEP-WALK,SKIPP
  76. 2150  REM   ** DATA FOR 2ND VERB PHRASES - V2$( )
  77. 2160  DATA CLOWN,SQUARE DANC,FLY,RID,SKINNY-DIPP,SWIMM,SING,BATH,SCRATCH,EAT
  78. 2170  DATA  LOUNG,DECORAT,BARK,WHISTL,ROAM,SCREECH,COOK,RAC,GALLOP,SNOR
  79. 2180  DATA  SWEEP,LEVITAT,CHATT,BELLOW
  80. 2200  REM ** DATA FOR FIRST PREP-OSITIONAL PHRASES - P1$( )
  81. 2210  DATA  IN A DARK CLOSET,UNDER THE BED,ON THE ROOF,IN THE SCHOOLYARD,IN A SUPERMARKET,IN THE JUNGLE,UP A TALL TREE,IN A TRASH CAN,AT THE OFFICE,IN A WET TENT
  82. 2220  DATA  ON A BUSY STREET,IN A BUBBLE BATH,AT THE BEACH,IN THE MOUNTAINS,IN A RESTAURANT,IN A DARK CAVE,IN A CABOOSE,ON A JET PLANE,IN A LOCKER ROOM,IN A HUMID HAMPER
  83. 2230  DATA IN A HAMMOCK,ON AN ISLAND,ON A FLAT ROCK,IN THE MOVIE THEATER
  84. 2250  REM  ** DATA FOR 2ND PREP. PHRASES - P2$( )
  85. 2260  DATA  ON A BICYCLE,ON A BOOMERANG,ON A VACUUM CLEANER,ON A BROOMSTICK,IN A PURPLE CANOE,ON A LAWN MOWER,IN A BABY CARRIAGE,IN A ROCKING CHAIR, ON A SURFBOARD,IN AN AMBULANCE
  86. 2270  DATA IN A SUBMARINE,ON A SCOOTER,ON A YELLOW BALLOON,ON A BOX KITE,ON A FIRE TRUCK,IN A TAXI,ON A RAFT,ON A SKATEBOARD,ON ROLLER SKATES,IN A BEAT-UP OLD VAN
  87. 2280  DATA IN A HEARSE,IN A LITTLE RED WAGON,ON A FLYING CARPET,IN A FLYING SAUCER
  88. 2300  REM  ** DATA FOR 3RD PREP. PHRASES - P2$( )
  89. 2310  DATA   AT A PICNIC,AND HAVING A GREAT TIME,IN THE NUDE,WHILE WATCHING T.V,ON AN ICEBERG,WHILE BUYING A PIZZA,IN A GO-CART,WHILE TYING THEIR SHOES,IN A SECRET PASSAGEWAY,WHILE PLAYING CARDS
  90. 2320  DATA WHILE HORSEBACK RIDING,ON THE DANCE FLOOR,WHILE ATTENDING A MEETING,WHILE PLAYING TENNIS,AT A FOOTBALL GAME,WHILE USING THE COMPUTER,ON A MOUNTAIN TOP,WHILE ACTING IN A PLAY,WHILE SHOPPING A SEARS
  91. 2330  DATA  WHILE KNITTING A SWEATER,WHILE AT A FASHION SHOW,WHILE DOING THE DISHES,WHILE PAINTING A MURAL,WHILE EATING SARDINES
  92. 2400  REM   ** DATA FOR WHAT     HAPPENED PHRASES - H$( )
  93. 2410  DATA PUSHED THEM OFF A CLIFF,TOOK THEM TO JAIL,GAVE THEM A LIFT TO A HAUNTED HOUSE,TOOK THEM TO A CASTLE,CHASED THEM INTO A DARK ROOM
  94. 2420  DATA FLEW THEM TO HEAVEN,SWEPT THEM OFF TO THE MOON,TOOK THEM ON A SPACE VOYAGE,TOOK THEM TO CHURCH,TOOK THEM TO A WEDDING
  95. 2430  DATA DRAGGED THEM TO THE DENTIST,PUSHED THEM INTO A PHONE BOOTH,TOOK THEM TO A BEACH PARTY,SENT THEM TO MARS,SHOVED THEM INTO A LAKE
  96. 2440  DATA TOOK THEM TO THE ZOO,LEFT THEM IN THE DESERT,TOOK THEM TO A CANDY FACTORY,LEFT THEM IN A COAL MINE,HID THEM IN THE ATTIC
  97. 2450  DATA  PUT THEM IN A DAMP CELLAR,BEAMED THEM UP,DROVE THEM TO THE HOSPITAL,DROVE THEM TO THE AIRPORT
  98. 2500  REM  ** DATA FOR WHEN      PHRASES - WH$( )
  99. 2510  DATA MET A TEACHER,FOUND A POLICEMAN,SPIED A WITCH,ENCOUNTERED A GHOST,SUBDUED A MONSTER
  100. 2520  DATA SAW A GIANT RAT,MET AN ELEPHANT,DISCOVERED A DRAGON,TAMED A RATTLESNAKE,SAW A ROBOT
  101. 2530  DATA ATTRACTED AN AARDVARK,SPOTTED A ROACH,ARGUED WITH A SALESMAN,CAPTURED A CATIPILLER,UNVEILED A UNICORN
  102. 2540  DATA TRICKED A TIGER,WRESTLED A WALRUS,PLAYED WITH A PLATYPUS,MET A MERMAID,BATTLED A BEAST
  103. 2550  DATA HARASSED A HIPPO,MET A MAILMAN,SAW A SERPENT,RAN INTO A RABBIT
  104. 2600  REM ** DATA FOR WHERE      PHRASES - WH$( )
  105. 2610  DATA KIDS WERE,HIPPIES WERE,PIRATES WERE,ANTS WERE,DRAGONS WERE,EVERYONE WAS,INDIANS WERE,MARTIANS WERE,MICKEY MOUSE WAS,YOGI BEAR WAS
  106. 2620  DATA NUDISTS WERE,DRACULA WAS,THE BRADY BUNCH WAS,CAPTAIN KIRK WAS,MR. SPOCK WAS,THE MAID WAS,THE U.S. MARINES WERE,DENNIS THE MENACE WAS,DONALD DUCK WAS,THE MAYOR WAS
  107. 2630  DATA ASTRONAUTS WERE,MOVIE STARS WERE,MR. BILL WAS,SCOUT LEADERS WERE
  108. 3000  REM ======================
  109. 3010  REM PUBLIC DOMAIN PROGRAM
  110. 3020  REM CONTRIBUTED TO
  111. 3030  REM SOFTDISK MAGAZETTE
  112. 3040  REM OCTOBER 1982
  113. 3050  REM ======================